Macro/投稿/146

http://sakura.qp.land.to/?Macro%2F%C5%EA%B9%C6%2F146


Top > Macro > 投稿 > 146

複数行置換

  • ページ: Macro/投稿
  • 作者: maru
  • カテゴリー: vbs
  • 投稿日: 2006-08-10 (木) 01:41:18

メッセージ

filewshReplace2.vbsをお使いください。wshReplace.vbsには区切り文字自身を置換文字として指定できないバグあります(2006-08-17)

  • WSHのRegExpオブジェクトを使用した簡易な複数行置換機能.
  • 一応期待の動作をしているように見える.
wshReplace.png

バグ修正

  • 区切り文字自身を'\'でエスケープするように修正
  • ついでに任意の文字を区切り文字として利用できるように変更
  • WSHのRegExpでは置換後にエスケープ文字が使えないようなのでvbCrとvbLfの変換処理を追加
filewshReplace2.vbs
  0
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
'------------------------------------------------
'【名 称】wshReplace2.vbs
'【機 能】WSHのRegExpを使った簡易な複数行置換マクロ
'範囲選択時:選択範囲を置換
'非選択時:ファイル全体を置換
'------------------------------------------------
Private Sub Main
    sPattern = InputBox("置換パターンを入力してください", "簡易複数行置換マクロ", "s/置換前/置換後/gi")
 
    '置換のみ対応
    If Left(sPattern, 1) <> "s" Then Exit Sub
    If Len(sPattern) < 5 Then Exit Sub
 
    '区切り文字の取得
    sDelim = Mid(sPattern, 2, 1)
    
    'RegExpオブジェクト生成
    Set oRegExp = New RegExp
 
    '区切り文字をいったんすべてタブに置換して
    oRegExp.Pattern = sDelim
    oRegExp.Global = True
    sRet = oRegExp.Replace(sPattern, vbTab)
    
    'もし区切り文字がエスケープされていたら元に戻す
    oRegExp.Pattern = "\\" & vbTab
    oRegExp.Global = True
    sRet = oRegExp.Replace(sRet, sDelim)
 
    '置換前切り出し
    iStart = 3
    iEnd = InStr(iStart, sRet, vbTab)
    If iStart >= iEnd Then Exit Sub
    sBefore = Mid(sRet, iStart, iEnd - iStart)
 
    '置換後切り出し
    iStart = iEnd + 1
    iEnd = InStr(iStart, sRet, vbTab)
    If iStart > iEnd Then Exit Sub
    sAfter = Mid(sRet, iStart, iEnd - iStart)
 
    '置換後文字列の改行コード生成
    oRegExp.Pattern = "\\r"
    oRegExp.Global = True
    sAfter = oRegExp.Replace(sAfter, vbCr)
    oRegExp.Pattern = "\\n"
    oRegExp.Global = True
    sAfter = oRegExp.Replace(sAfter, vbLf)
 
    '修飾子判定
    iStart = iEnd + 1
    If Instr(iStart, sRet, "g") Then oRegExp.Global = True
    If Instr(iStart, sRet, "i") Then oRegExp.IgnoreCase = True
 
    '置換処理
    oRegExp.Pattern = sBefore
    If GetSelectedString(CLng(0)) = "" Then SelectAll
    InsText CStr(oRegExp.Replace(GetSelectedString(CLng(0)), sAfter))
 
    Set oRegExp = Nothing
End Sub
 
Call Main


URL B I U SIZE Black Maroon Green Olive Navy Purple Teal Gray Silver Red Lime Yellow Blue Fuchsia Aqua White

添付ファイル: filewshReplace.png 253件 [詳細] filewshReplace2.vbs 2542件 [詳細] filewshReplace.vbs 307件 [詳細]

リロード   新規 編集 凍結 差分 添付 複製 名前変更   ホーム 一覧 単語検索 最終更新 バックアップ リンク元   ヘルプ   最終更新のRSS
Last-modified: 2014-02-04 (火) 12:33:47 (3696d)